Misc. pulse programs¶
Pulse program for measurement of B1 amplitudes¶
Here we provide our pulse program for direct measurement of B1 amplitudes. As always, the pulse program is in Bruker format. For the pseudo-3D version, please see the next section.
You can download the pulse program here - hsqcCWcalib
;hsqcCWcalib
;
;avance-version (05/31/2017)
;15N CW power measurement
;with decoupling during acquisition
;using f3 - channel
;using flip-back pulse
;
;
;
;$CLASS=HighRes
;$DIM=1D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>
define pulse pcw
"p2=p1*2"
"p22=p21*2"
"plw0=0"
"plw16=plw3*pow((p21/pcpd3),2)" ; 15N decoupling power
"plw19=plw1*pow((p1/pcpd1),2)" ; 1H decoupling power
"spw1=plw1*pow((p1/(p11*0.5889)),2)" ; Water-flip-back pulse power
"d11=30m"
"d0=3u"
"in0=inf1"
"DELTA=d24-p16-d16"
"DELTA1=d26-p16-d16-p11-12u"
"acqt0=0"
baseopt_echo
1 ze
d11 pl16:f3
2 d11 do:f3
"pcw=d0"
d1 pl0:f1 pl3:f3
(p11:sp1 ph3):f1
4u
4u pl1:f1
;---------------------------------------- refocused INEPT
(p1 ph0):f1
d26
(center (p2 ph0):f1 (p22 ph0):f3 )
d26
(center (p1 ph3):f1 (p21 ph4):f3 )
d24
(center (p2 ph0):f1 (p22 ph0):f3 )
d24 UNBLKGRAD
(p21 ph5):f3
;----------------------------------------
p16:gp1
d16 pl19:f1 pl25:f3
(p26 ph0):f1
4u cpds1:f1 ph1
;---------------------------------------- t1 evolution & CW spinlock
(pcw ph6):f3
;----------------------------------------
4u do:f1
(p26 ph2):f1
p16:gp1
d16 pl1:f1 pl3:f3
;---------------------------------------- Reverse INEPT
(p21 ph7):f3
p16:gp2
d16
DELTA
(center (p2 ph0):f1 (p22 ph0):f3 )
DELTA
p16:gp2
d16 pl0:f1
(p21 ph3):f3
(p11:sp1 ph8):f1
4u
4u pl1:f1
(p1 ph8):f1
4u
p16:gp3
d16
DELTA1 pl0:f1
(p11:sp1 ph2):f1
4u
4u pl1:f1
(center (p2 ph0) (p22 ph0):f3 )
4u pl0:f1
(p11:sp1 ph2):f1
4u
DELTA1
p16:gp3
d16 pl16:f3
4u BLKGRAD
go=2 ph31 cpds3:f3
d11 do:f3 mc #0 to 2
F1PH(, caldel(d0, +in0))
exit
ph0 =0
ph1 =1
ph2 =2
ph3 =1 1 3 3
ph4 =0 2
ph5 =1 3 3 1 1 3 3 1 3 1 1 3 3 1 1 3
ph6 =0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2 1 1 1 1 1 1 1 1 3 3 3 3 3 3 3 3
ph7 =0 2
ph8 =0 0 0 0 2 2 2 2
ph31=0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0
;pl1 : f1 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl16: f3 channel - power level for CPD/BB decoupling
;pl19: f1 channel - power level for CPD/BB decoupling
;pl25: f3 channel - power level for spinlock
;sp1 : f1 channel - shaped pulse 90 degree
;spnam1: Sinc1.1000
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p11: f1 channel - 90 degree shaped pulse
;p16: homospoil/gradient pulse [1 msec]
;p21: f3 channel - 90 degree high power pulse
;p26: f1 channel - 90 degree pulse at pl19
;d1 : relaxation delay; 1-5 * T1
;d11: delay for disk I/O [30 msec]
;d16: delay for homospoil/gradient recovery
;d24: 1/(4J(NH)) [2.688 msec]
;d26: 1/(4J(NH)) [2.688 msec]
;inf1: 1/SW(N) = 2 * DW(N)
;in0: 1/(2 * SW(N)) = DW(N)
;nd0: 1
;NS: 2 * n
;DS: 8
;FnMODE: TPPI in F1
;cpd1: decoupling according to sequence defined by cpdprg1
;cpd3: decoupling according to sequence defined by cpdprg3
;pcpd1: f1 channel - 90 degree pulse for decoupling sequence
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence
;use gradient ratio: gp 1 : gp 2 : gp 3
; 80 : 5 : 20
;for z-only gradients:
;gpz1: 80%
;gpz2: 5%
;gpz3: 20%
;use gradient files:
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100
Pulse program for measurement of B1 amplitudes (pseudo-3D version)¶
This is the pulse program for direct measurement of B1 amplitudes as a pseudo-3D version.
You can download the pulse program here - hsqcCWcalib3d
;hsqcCWcalib3d
;
;avance-version (05/31/2017)
;15N CW power measurement
;with decoupling during acquisition
;using f3 - channel
;using flip-back pulse
;as pseudo3D
;
;
;$CLASS=HighRes
;$DIM=1D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>
define list<power> va15N=<$VALIST>
define pulse pcw
"p2=p1*2"
"p22=p21*2"
"plw0=0"
"plw16=plw3*pow((p21/pcpd3),2)" ; 15N decoupling power
"plw19=plw1*pow((p1/pcpd1),2)" ; 1H decoupling power
"spw1=plw1*pow((p1/(p11*0.5889)),2)" ; Water-flip-back pulse power
"d11=30m"
"d10=3u"
"in10=inf2"
"l11=0"
"DELTA=d24-p16-d16"
"DELTA1=d26-p16-d16-p11-12u"
"acqt0=0"
baseopt_echo
aqseq 312
1 ze
d11 pl16:f3
2 d11 do:f3
"va15N.idx=(l11)"
"pcw=d10"
d1 pl0:f1 pl3:f3
(p11:sp1 ph3):f1
4u
4u pl1:f1
;---------------------------------------- refocused INEPT
(p1 ph0):f1
d26
(center (p2 ph0):f1 (p22 ph0):f3 )
d26
(center (p1 ph3):f1 (p21 ph4):f3 )
d24
(center (p2 ph0):f1 (p22 ph0):f3 )
d24 UNBLKGRAD
(p21 ph5):f3
;----------------------------------------
p16:gp1
d16 pl19:f1 va15N:f3
(p26 ph0):f1
4u cpds1:f1 ph1
;---------------------------------------- t1 evolution & CW spinlock
(pcw ph6):f3
;----------------------------------------
4u do:f1
(p26 ph2):f1
p16:gp1
d16 pl1:f1 pl3:f3
;---------------------------------------- Reverse INEPT
(p21 ph7):f3
p16:gp2
d16
DELTA
(center (p2 ph0):f1 (p22 ph0):f3 )
DELTA
p16:gp2
d16 pl0:f1
(p21 ph3):f3
(p11:sp1 ph8):f1
4u
4u pl1:f1
(p1 ph8):f1
4u
p16:gp3
d16
DELTA1 pl0:f1
(p11:sp1 ph2):f1
4u
4u pl1:f1
(center (p2 ph0) (p22 ph0):f3 )
4u pl0:f1
(p11:sp1 ph2):f1
4u
DELTA1
p16:gp3
d16 pl16:f3
4u BLKGRAD
go=2 ph31 cpds3:f3
d11 do:f3 mc #0 to 2
F1QF(calclc(l11, 1))
F2PH(, caldel(d10, +in10))
exit
ph0 =0
ph1 =1
ph2 =2
ph3 =1 1 3 3
ph4 =0 2
ph5 =1 3 3 1 1 3 3 1 3 1 1 3 3 1 1 3
ph6 =0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2 1 1 1 1 1 1 1 1 3 3 3 3 3 3 3 3
ph7 =0 2
ph8 =0 0 0 0 2 2 2 2
ph31=0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0
;pl1 : f1 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl16: f3 channel - power level for CPD/BB decoupling
;pl19: f1 channel - power level for CPD/BB decoupling
;pl25: f3 channel - power level for spinlock
;sp1 : f1 channel - shaped pulse 90 degree
;spnam1: Sinc1.1000
;p1 : f1 channel - 90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p11: f1 channel - 90 degree shaped pulse
;p16: homospoil/gradient pulse [1 msec]
;p21: f3 channel - 90 degree high power pulse
;p26: f1 channel - 90 degree pulse at pl19
;d1 : relaxation delay; 1-5 * T1
;d11: delay for disk I/O [30 msec]
;d16: delay for homospoil/gradient recovery
;d24: 1/(4J(NH)) [2.688 msec]
;d26: 1/(4J(NH)) [2.688 msec]
;inf2: 1/SW(N) = 2 * DW(N)
;in10: 1/(2 * SW(N)) = DW(N)
;nd10: 1
;NS: 2 * n
;DS: 8
;td1: number of frequencies in va-list
;td2: number of experiments in F2
;FnMODE: QF in F1
;FnMODE: TPPI in F2
;cpd1: decoupling according to sequence defined by cpdprg1
;cpd3: decoupling according to sequence defined by cpdprg3
;pcpd1: f1 channel - 90 degree pulse for decoupling sequence
;pcpd3: f3 channel - 90 degree pulse for decoupling sequence
;use gradient ratio: gp 1 : gp 2 : gp 3
; 80 : 5 : 20
;for z-only gradients:
;gpz1: 80%
;gpz2: 5%
;gpz3: 20%
;use gradient files:
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100
;gpnam3: SMSQ10.100